比較とジャンプ

> 汎用命令 (3)

ジャンプ命令には、無条件ジャンプ (JMP) と、条件ジャンプ (Jcc) があります。

無条件ジャンプは、相対位置または絶対位置を指定して、移動します。

条件ジャンプは、ステータスフラグの状態によって、ジャンプするか、後続の命令をそのまま実行します。
条件ジャンプは、相対位置での移動しか行えません。

ジャンプは、rIP の値を変更することで、次の命令の実行位置を変更します。

以下は、JMP 命令のエンコードを確認するためだけのコードです。実際には実行しないでください。

nasm の -l オプションで、出力とソースコードを並べた形式のテキストを出力できます。

section .text

testfunc:
    nop ; 90
label1:
    jmp testfunc  ; EB FD
    jmp label2    ; EB 0A
    times 10 db 0 ; 0(1byte) x 10
label2:
    ret

$ nasm -f elf64 test.asm -l test.txt

以下のサンプルでは、LEA 命令で移動先の絶対アドレスを取得し、一度メモリに書き込んだ後、JMP 命令で、そのメモリ位置の値を参照し、絶対位置にジャンプします。

default rel
global testfunc

section .data

addr: dq 0

section .text

testfunc:
    lea rax, [label1] ; label1 の絶対アドレスを RAX にセット
    mov [addr], rax   ; addr のメモリ位置に値を書き込む
    jmp [addr]        ; FF 25 BC 2E 00 00
    nop
label1:
    ret

JMP reg/mem64 | FF /4

上記の場合、jmp rax としても、結果は同じです。

※このコードの場合、default rel により、RIP 相対アドレスでアドレス指定されるため、[<ラベル>] は、[RIP + offset] に置き換わります。

２つの値を比較したい場合、CMP 命令や TEST 命令を使います。

CMP 命令は、A - B による減算を行い、結果をフラグにセットします。
TEST 命令は、論理 AND を行って、結果をフラグにセットします (PF, ZF, SF)。

値が 0 かどうかを比較したい場合は、以下のようにして TEST 命令を使うことができます。

test eax, eax ; 同じ値で AND
jne no_zero   ; 結果が 0 でないならジャンプ
; zero
no_zero:

同じ値で AND を行った場合、両方のビットが 1 の場合のみ 1 になるので、ビットが一つでも 1 になっていれば、0 以外の値になります。
すべてのビットが 0 (値が 0) の場合のみ、結果の値が 0 になり、ZF が 1 になります。

Jcc (J の後、条件によって異なる名前が続く) 命令は、CMP などの比較命令や演算命令の後に使います。
ステータスフラグが条件に一致している場合は、ジャンプします。条件が一致しない場合は、そのまま後続の命令を実行します。

以下は、符号付き 8bit 整数で、A - B を行った場合の、ステータスフラグの結果です。

1 - 2 = -1	OF = 0, SF = 1, ZF = 0 (A < B)
2 - 1 = 1	OF = 0, SF = 0, ZF = 0 (A > B)
-128 - 1 = -129(0x7F) = 127	OF = 1, SF = 0, ZF = 0 (A < B)
127 - -1 = 128(0x80) = -128	OF = 1, SF = 1, ZF = 0 (A > B)

上の２つのように、オーバーフローが発生しなかった場合 (OF = 0 時)、
結果が負 [OF = 0 and SF = 1] であれば、「A - B = 負」ということなので、つまり、A < B という条件に当てはまります。
結果が正 [OF = 0 and SF = 0] であれば、「A - B = 正」ということなので、つまり、A > B という条件に当てはまります。

下の２つのように、オーバーフローが発生した場合 (OF = 1 時)、結果の符号が、正か負か (SF = 0 or 1) で、どの形式によるオーバーフローなのかが判断できます。
結果が正 [OF = 1 and SF = 0] であれば、「負−正＝正」ということなので、A が負で B が正であるなら、A < B という条件に当てはまります。
結果が負 [OF = 1 and SF = 1] であれば、「正−負＝負」ということなので、A が正で B が負であるなら、A > B という条件に当てはまります。

上記をまとめると、OF != SF であれば、A < B となり、OF = SF であれば、A > B ということになります。

あとは、ZF が 1 かどうかで、<= や >= を判断することができます。